(* dm at mayart.de, 2006

Adobe Illustrator CS
Das Kerning nach einem bestimmten Zeichen im *gesamten Dokument* ändern.

Das Skript muss im Apple Skripteditor als *.scpt gespeichert und kann
unter Programme > Adobe Illustrator CSx > Vorgaben > Skripte abgelegt werden. 
Nach Neustart von Illustrator findet man es im Menü Datei > Skripten. 

Es geht auch mit dem Skript Menü in OS X (installieren mit AppleScript Utility in Programme > Applescript)
oder besser mit FastScripts: <http://www.red-sweater.com/fastscripts/index.html>.
Hier liegen die Skripte in ~/Library/Scripts/...

*)

set searchString to text returned of (display dialog "Von welchen Zeichen das „Kerning nach“ verändern?" default answer "1")

set k to text returned of (display dialog "Bitten den Kerning-Wert eingeben:" default answer "-75") as integer

try
	tell application "Adobe Illustrator"
		
		set myDok to document 1
		
		set textArtItemCount to (count of text frames in myDok)
		if (textArtItemCount > 0) then
			
			repeat with itemCounter from 1 to textArtItemCount
				if (((contents of text frame itemCounter of myDok) as string) contains searchString) then
					
					set myChars to (characters of text frame itemCounter of myDok whose contents = searchString)
					
					repeat with c in myChars
						set kerning of character after c to k
						
					end repeat
					
				end if
			end repeat
		end if
	end tell
on error error_message
	display dialog error_message
end try